{| |} expression blocks deprecated.

lib/std/core/allocators/dynamic_arena.c3

@@ -164,14 +164,21 @@ fn void*! DynamicArenaAllocator.acquire(&self, usz size, AllocInitType init_type
 {
 	alignment = alignment_for_allocation(alignment);
 	DynamicArenaPage* page = self.page;
-	void* ptr = {|
+
+	void* ptr @noinit;
+	do SET_DONE:
+	{
 		if (!page && self.unused_page)
 		{
 			self.page = page = self.unused_page;
 			self.unused_page = page.prev_arena;
 			page.prev_arena = null;
 		}
-		if (!page) return self._alloc_new(size, alignment);
+		if (!page)
+		{
+			ptr = self._alloc_new(size, alignment)!;
+			break SET_DONE;
+		}
 		void* start = mem::aligned_pointer(page.memory + page.used + DynamicArenaChunk.sizeof, alignment);
 		usz new_used = start - page.memory + size;
 		if ALLOCATE_NEW: (new_used > page.total)
@@ -188,15 +195,15 @@ fn void*! DynamicArenaAllocator.acquire(&self, usz size, AllocInitType init_type
 					break ALLOCATE_NEW;
 				}
 			}
-			return self._alloc_new(size, alignment);
+			ptr = self._alloc_new(size, alignment)!;
+			break SET_DONE;
 		}
 		page.used = new_used;
 		assert(start + size == page.memory + page.used);
-		void* mem = start;
-		DynamicArenaChunk* chunk = (DynamicArenaChunk*)mem - 1;
+		ptr = start;
+		DynamicArenaChunk* chunk = (DynamicArenaChunk*)ptr - 1;
 		chunk.size = size;
-		return mem;
-	|}!;
+	};
 	if (init_type == ZERO) mem::clear(ptr, size, mem::DEFAULT_MEM_ALIGNMENT);
 	return ptr;
 }

lib/std/core/string.c3

@@ -780,26 +780,28 @@ macro String.to_integer(string, $Type, int base = 10)
 	$Type value = 0;
 	while (index != len)
 	{
-		char c = {|
-			char ch = string[index++];
-			if (base_used != 16 || ch < 'A') return (char)(ch - '0');
-			if (ch <= 'F') return (char)(ch - 'A' + 10);
-			if (ch < 'a') return NumberConversion.MALFORMED_INTEGER?;
-			if (ch > 'f') return NumberConversion.MALFORMED_INTEGER?;
-			return (char)(ch - 'a' + 10);
-		|}!;
+		char c = string[index++];
+		switch
+		{
+			case base_used != 16 || c < 'A':  c -= '0';
+			case c <= 'F':                    c -= 'A' - 10;
+			case c < 'a' || c > 'f':          return NumberConversion.MALFORMED_INTEGER?;
+			default:                          c -= 'a' - 10;
+		}
 		if (c >= base_used) return NumberConversion.MALFORMED_INTEGER?;
-		value = {|
+		do
+		{
 			if (is_negative)
 			{
 				$Type new_value = value * base_used - c;
 				if (new_value > value) return NumberConversion.INTEGER_OVERFLOW?;
-				return new_value;
+				value = new_value;
+				break;
 			}
 			$Type new_value = value * base_used + c;
 			if (new_value < value) return NumberConversion.INTEGER_OVERFLOW?;
-			return new_value;
-		|}!;
+			value = new_value;
+		};
 	}
 	return value;
 }

lib/std/core/string_to_real.c3

@@ -376,10 +376,7 @@ macro double! hexfloat(char[] chars, int $bits, int $emin, int sign)
 		else
 		{
 			got_digit = true;
-			int d = {|
-				if (c > '9') return (c | 32) + 10 - 'a';
-				return c - '0';
-			|};
+			int d = c > '9' ? ((c | 32) + 10 - 'a') : (c - '0');
 			switch
 			{
 				case dc < 8:

lib/std/os/subprocess.c3

@@ -75,10 +75,12 @@ fn void! create_named_pipe_helper(void** rd, void **wr) @local @if(env::WIN32)
 fn WString convert_command_line_win32(String[] command_line) @inline @if(env::WIN32) @local
 {
 	DString str = dstring::temp_with_capacity(512);
-	foreach (i, s : command_line)
+	foreach LINE: (i, s : command_line)
 	{
 		if (i != 0) str.append(' ');
-		bool needs_escape = {|
+
+		do CHECK_WS:
+		{
 			foreach (c : s)
 			{
 				switch (c)
@@ -86,16 +88,12 @@ fn WString convert_command_line_win32(String[] command_line) @inline @if(env::WI
 					case '\t':
 					case ' ':
 					case '\v':
-						return true;
+						break CHECK_WS;
 				}
 			}
-			return false;
-		|};
-		if (!needs_escape)
-		{
 			str.append(s);
-			continue;
-		}
+			continue LINE;
+		};
 		str.append('"');
 		foreach (j, c : s)
 		{
@@ -178,12 +176,13 @@ fn SubProcess! create(String[] command_line, SubProcessOptions options = {}, Str
 
 		start_info.hStdOutput = wr;
 
-		{|
+		do
+		{
 			if (options.combined_stdout_stderr)
 			{
 				stderr = stdout;
 				start_info.hStdError = start_info.hStdOutput;
-				return;
+				break;
 			}
 			if (options.read_async)
 			{
@@ -202,8 +201,7 @@ fn SubProcess! create(String[] command_line, SubProcessOptions options = {}, Str
 				if (!stderr) return SubProcessResult.FAILED_TO_OPEN_STDERR?;
 			}
 			start_info.hStdError = wr;
-
-		|}!;
+		};
 		void *event_output;
 		void *event_error;
 		if (options.read_async)
@@ -323,11 +321,17 @@ fn SubProcess! create(String[] command_line, SubProcessOptions options = {}, Str
 	CFile stdin = libc::fdopen(stdinfd[1], "wb");
 	libc::close(stdoutfd[1]);
 	CFile stdout = libc::fdopen(stdoutfd[0], "rb");
-	CFile stderr = {|
-		if (options.combined_stdout_stderr) return stdout;
+	CFile stderr @noinit;
+	do
+	{
+		if (options.combined_stdout_stderr)
+		{
+			stderr = stdout;
+			break;
+		}
 		libc::close(stderrfd[1]);
-		return libc::fdopen(stderrfd[0], "rb");
-	|};
+		stderr = libc::fdopen(stderrfd[0], "rb");
+	};
 	return {
 		.stdin_file = stdin,
 		.stdout_file = stdout,